Excel VBA Dates & Time, Format Function, User Defined Date, Number & String Formats

 

---------------------------------------------------------------------------------------------------------------

Contents:

Excel VBA Dates & Time

Format Function in VBA

Named Date/Time Formats

Named Numeric Formats

Characters used to create User-Defined Number Formats with the VBA Format Function

Characters used to create User-Defined Date & Time Formats with the VBA Format Function

Characters used to create User-Defined String Formats with the VBA Format Function

 --------------------------------------------------------------------------------------------------------------- 

 

 

Excel VBA Dates & Time

 

Excel Dates Equate to Serial Numbers - Excel stores all dates as integers and all times as decimal fractions. Your System's Locale settings determines display format for Numbers, Currency, Date & Time. With the VBA Format function you can create User-Defined Date & Time Formats, Number Formats & String Formats, besides using predefined Named Date/Time & Numeric Formats. The Format function formats and returns an expression (String value) as per the specified format. Your system-defined formats include the Short Date Format, Long Date Format, Short Time Format, Long Time Format, and the Number & Currency Formats, which are specified in your computer's regional settings, which determine your default display formats.

 

 

Date Data Type in VBA: Date equates to a numeric value which is the count of number of days elapsed from a certain referenced date. Dates are stored as 64-bit (8-byte) Double Precision floating-point numbers.

 

Variable Data Type Storage Size Range or Type of Values it Stores
 Date 8-bytes Holds either the date or the time, or both. Values can range from January 1, 100 to December 31, 9999. After declaring the variable, you can assign a value to it. A date value must be entered between two # signs, viz.  
DateOfBirth = #2/15/1961#
TimeOfBirth = #10:05 AM#
MarriageDate = #2/19/94 17:30#

 

Enclosing a date within number signs (#) ensures that the date literal will actually remain the date value which you actually mean to refer or use in your code. Generally the locale in which your application might be running (ie. Code Locale), determines the actual meaning of date value you enter, for ex. if you mean July 02, 2010 in a locale using mm/dd/yyyy, entering 07/02/2010 will compile your code correctly but entering 07/02/2010 in a locale using dd/mm/yyyy format will erroneously interpret as February 07, 2010 in your code. Using number signs (#) ensures that the date literal remains independent of your computer's date and time format settings. Date literal is the date format specified by the locale settings for your code (ie. Code Locale). #7/2/2010# is the date literal that represents July 02, 2010, where English-U.S. is the locale setting for your application.

 

System's Locale settings vs. Code Locale: The System's Locale settings is the locale of the user who runs your program - the User Locale determines which default settings a user wants for formatting Numbers, Currency, Time & Date (used as a reference for user output) and uses Control Panel settings provided by the operating system. System-defined Format is dependent on your System's Locale settings. The code locale is always English/U.S. in Visual Basic, irrespective of the international version being used. Short Time format and Short Date format of the Code Locale are used to Display Date and Time in the development environment ie. VBE in Excel.

 

To ensure that the date is correctly interpreted in any System Locale, enter dates within number signs (#), in code, in the format #month/day/year#. Because only English/U.S. is allowed in Visual Basic as a programming locale, the date will be the same to a user wherever your application is run. See below example.

 

 

Example: System-defined format (format specified in your computer's regional settings) - Short Date Format is "dd-mm-yy" (English/U.K.) - refer Image 1a

 

 

Sub DateLiteral_1()

'system-defined format (format specified in your computer's regional settings) - Short Date Format is "dd-mm-yy" (English/U.K.) - refer Image 1a


Dim MyDate As Variant, MyDate1 As Variant


'short date format of your Code Locale is always English/U.S. in Visual Basic, which determines display of Date in VBE

MyDate = #7/5/2014#

'below format will assume your system-defined format:

MyDate1 = "7/5/2014"

'returns "Saturday, July 5, 2014"

ActiveCell.Offset(1, 0) = Format(MyDate, "dddd, mmmm d, yyyy")

ActiveCell.Offset(1, 1) = "date within number signs (# #)"

'returns "Wednesday, May 7, 2014"

ActiveCell.Offset(2, 0) = Format(MyDate1, "dddd, mmmm d, yyyy")

ActiveCell.Offset(2, 1) = "date within double quotes"


End Sub

 

 

 

Example: System-defined format (format specified in your computer's regional settings) - Short Date Format is "m/d/yyyy"  (English/U.S.) - refer Image 1b

 

 

Sub DateLiteral_2()

'system-defined format (format specified in your computer's regional settings) - Short Date Format is "m/d/yyyy"  (English/U.S.) - refer Image 1b

 

Dim MyDate As Variant, MyDate1 As Variant

 

'short date format of your Code Locale is always English/U.S. in Visual Basic, which determines display of Date in VBE

MyDate = #7/5/2014#

'below format will assume your system-defined format:

MyDate1 = "7/5/2014"


'returns "Saturday, July 5, 2014"

ActiveCell.Offset(1, 0) = Format(MyDate, "dddd, mmmm d, yyyy")

ActiveCell.Offset(1, 1) = "date within number signs (# #)"


'returns "Saturday, July 5, 2014"

ActiveCell.Offset(2, 0) = Format(MyDate1, "dddd, mmmm d, yyyy")

ActiveCell.Offset(2, 1) = "date within double quotes"


End Sub

 

 

 

Format specified in your computer's regional settings - Short Date / Long Date Format can be set or changed by the individual user manually  from the Formats tab of the Region item in Control Panel in Windows 8. Refer Image 2.

 

 

 

Excel Dates Equate to Serial Numbers:

 

Excel stores all dates as integers and all times as decimal fractions. With this system, Excel can add, subtract, or compare dates and times just like any other numbers, and all dates are manipulated by using this system. In this system, the serial number 1 represents 1/1/1900 12:00:00 AM, the first supported day from when the Excel calendar starts. Bug in Excel: Excel erroneously treats 1900 as a leap year, which has presumably been done knowingly by Microsoft to provide compatibility with Lotus 1-2-3, and so actually the bug would have been in Lotus 123 (Excel's predecessor).

 

In Excel, Dates equate to a "serial number" (which is a numeric value) that is the count of number of days elapsed from a certain referenced date. Dates are stored as 64-bit (8-byte) Double Precision floating-point numbers. The integer part (values to the left of decimal) is the number of days elapsed since January 1, 1900. For example, January 1, 1900 is stored as 1; January 2, 1900 is stored as 2; March 15, 2001 is stored as 36,965. The fractional part (values to the right of decimal) holds time information, and represents the time as a fraction of a whole day. For example, 12.00AM (midnight) is stored as 0; 6:00AM is stored as 0.25; 12.00PM (noon) is stored as 0.5; 6:00PM is stored as 0.75; 6:00:30PM is stored as 0.750347222. To check the "serial number" of a date and time simply format the cell as "General" or format to number - conversely type a number in Excel and formatting the cell to date format will display the equivalent date. The Date and Time of "10/3/1954  6:00:00 AM" has a serial number of 20000.25.

 

Note that where the 1900 date system is used by Excel for Windows, but Excel for Mac uses the 1904 date system so that typing the number 1 in Excel and formatting it in date format will display 1/2/1904 12:00:00 AM in Excel for Mac while Excel for Windows displays it as 1/1/1900 12:00:00 AM. In Mac, you can change to the 1900 date system by clearing the 1904 date system in the Calculation tab (in Preferences) whereas in Excel for Windows you can change to the 1904 date system - in Excel 2007 click the Microsoft Office Button image, click Excel Options, and then click the Advanced category and  in the 'When calculating this workbook' options select the 'Use 1904 date system'.

 

 

 

Format Function in VBA

 

The vba Format function formats and returns an expression (String value) as per the specified format. Syntax: Format(expression,format,firstdayofweek,firstweekofyear). It is necessary to specify the expression argument, which is any expression you wish to format. The other 3 arguments are optional to specify. The format argument specifies a named or user-defined format expression - (i) to format numbers (or dates/times), you will use predefined named numeric (or date/time) formats or create user-defined numeric (or date/time) formats; (ii) to format date and time serial numbers, you will use date/time formats or numeric formats; (iii) to format strings you will create user-defined string formats. You can also use constants to specify the first day of the week or the first week of the year in the arguments of firstdayofweek and firstweekofyear respectively.

 

Formatting a number by omitting the format argument will return a String representation of the number, similar to using the Str vba function, but a positive number thus formatted will not include a leading space for the sign of number in the returned string like when using the Str function. 

 

While using the Format Function for Date formatting, you must specify the expression argument appropriately in Gregorian or Hijri depending if your Calendar property setting is Gregorian or Hijri.

 

Constants to be used for the argument firstdayofweek: vbUseSystem (value 0) - use NLS API setting; vbSunday (this is the default) (value 1) - Sunday; vbMonday (value 2) - Monday; vbTuesday (value 3) - Tuesday; vbWednesday (value 4) - Wednesday; vbThursday (value 5) - Thursday; vbFriday (value 6) - Friday; vbSaturday ( value 7) - Saturday.

 

Constants to be used for the argument firstweekofyear: vbUseSystem (value 0) - use NLS API setting; vbFirstJan1 (this is the default) (value 1) - start with week in which January 1 occurs; vbFirstFourDays (value 2) - start with the first week which has at least four days in the year; vbFirstFullWeek (value 3) - start with the first full week of the year which has all 7 days.

 

 

 

Named Date/Time Formats

 

Listed below are predefined named Date and Time formats. Your system setting determines the Date display.

 

Format Name Description
General Date Displays a date and/or time, ex. 8/14/12 6:28 PM. The integer part (values to the left of decimal) displays a date, ex. 8/14/12, the fractional part (values to the right of decimal) displays time, ex. 6:28 PM. Your system setting determines the Date display - you can display only a Date or only a Time or both Date & Time.
Long Date Long Date Format refers to your system-defined long date format ie. the long date format specified in your computer's regional settings, for example, Thursday, July 31, 2014.
Medium Date Medium Date Format displays a date using the medium date format appropriate for the language version of your Excel application (host application).
Short Date Short Date Format refers to your system-defined short date format ie. the short date format specified in your computer's regional settings, for example, 7/31/2014.
Long Time Long Time Format refers to your system-defined long time format ie. the long time format specified in your computer's regional settings, and typically includes hours, minutes, seconds, for example, 19:35:40.
Medium Time Medium Time Format displays time in 12-hour format showing hours and minutes and the AM/PM designator viz. 7:48 AM.
Short Time Short Time Format displays a time using the 24-hour format, and typically uses hours & minutes, for example, 19:35.

 

 

System-defined Format is dependent on your System's Locale settings:

 

System Locale controls the language used when displaying text in programs tha do not support Unicode. Applications affected by this setting are only those that do not use Unicode as their default character-encoding mechanism and hence this setting is not applicable to applications that are already Unicode-encoded. The system locale is a unique setting for each system and the administrator has to change it manually wherein the computer is required to be restarted for the changes to take effect. System locale can be set from the Administrative tab of the Region item in Control Panel in Windows 8.

 

The User Locale determines which default settings a user wants for formatting Numbers, Currency, Time & Date. The user locale can be set or changed by the individual user manually  from the Formats tab of the Region item in Control Panel in Windows 8. Locale-aware applications use this value to display formatted data.

 

Your System's Locale settings (User Locale) determines display format for Numbers, Currency, Time & Date by running your code whereas the short time format and short date format of your Code Locale (which is always English/U.S. in Visual Basic) determines display of Time & Date in the development environment.

 

 

Example: Using Predefined Named Date and Time formats - System Settings - English (United States)

 

Sub PredefinedNamedDateAndTimeFormats_1()
'Using Predefined Named Date and Time formats.

'Your system setting determines the Date and Time display for General Date, Long Date, Short Date & Long Time;
'Medium Date format is per the language version of your host Excel application;
'Short Time Format uses a 24-hour format, displays hours & minutes;

'SYSTEM SETTINGS SPECIFIED IN THE COMPUTER'S REGIONAL SETTINGS - English (United States):
'Long Time Format = h:mm:ss tt
'Long Date Format = dddd, MMMM d, yyyy
'Short Time Format = h:mm tt
'Short Date Format = M/d/yyyy
'M = month; m = minute
'AM & PM Symbol = AM & PM

'tt = AM Or PM

Dim MyDate As Variant, MyTime As Variant, SerialNo As Variant, str As Variant

SerialNo = "41851.87"

MyDate = #7/31/2014#

MyTime = #7:16:32 PM#

 

'returns "7/31/2014 8:52:48 PM"

str = Format(SerialNo, "General Date")

MsgBox str


'returns "Thursday, July 31, 2014"

str = Format(MyDate, "Long Date")

MsgBox str

 

'returns "31-July-14"

str = Format(MyDate, "Medium Date")

MsgBox str


'returns "7/31/2014"

str = Format(MyDate, "Short Date")

MsgBox str


'returns "7:16:32 PM"

str = Format(MyTime, "Long Time")

MsgBox str


'returns "07:16 PM"

str = Format(MyTime, "Medium Time")

MsgBox str


'returns "19:16"

str = Format(MyTime, "Short Time")

MsgBox str


End Sub

 

 

 

Example: Using Predefined Named Date and Time formats - System Settings - English (United Kingdom)

 

Sub PredefinedNamedDateAndTimeFormats_2()

'Using Predefined Named Date and Time formats.


'Your system setting determines the Date and Time display for General Date, Long Date, Short Date & Long Time;
'Medium Date format is per the language version of your host Excel application;
'Short Time Format uses a 24-hour format, displays hours & minutes;

'SYSTEM SETTINGS SPECIFIED IN THE COMPUTER'S REGIONAL SETTINGS - English (United Kingdom):
'Long Time Format = HH:mm:ss
'Long Date Format = dd MMMM yyyy
'Short Time Format = HH:mm
'Short Date Format = dd/MM/yyyy
'h/H = 12/24 hour

'M = month; m = minute


Dim MyDate As Variant, MyTime As Variant, SerialNo As Variant, str As Variant


SerialNo = "41851.87"

MyDate = #7/31/2014#

MyTime = #7:16:32 PM#


'returns "31/07/2014 20:52:48"

str = Format(SerialNo, "General Date")

MsgBox str


'returns "31 July 2014"

str = Format(MyDate, "Long Date")

MsgBox str


'returns "31-July-14"

str = Format(MyDate, "Medium Date")

MsgBox str


'returns "31/07/2014"

str = Format(MyDate, "Short Date")

MsgBox str


'returns "19:16:32"

str = Format(MyTime, "Long Time")

MsgBox str


'returns "07:16 PM"

str = Format(MyTime, "Medium Time")

MsgBox str


'returns "19:16"

str = Format(MyTime, "Short Time")

MsgBox str


End Sub

 

 

 

Named Numeric Formats

 

Listed below are predefined numeric format names.

 

Format Name Description
General Number General format cells have no specific number format and do not display the thousand separator.
Currency Currency format is used for general monetary values and displays number with the thousand separator. It typically displays two digits to the right of the decimal point and the currency symbol, final display being based on your system's locale settings.
Fixed Fixed format displays a minimum of one digit to the left and two digits to the right of the decimal point.
Standard Standard format displays the thousand separator and a minimum of one digit to the left and two digits to the right of the decimal point.
Percent Percent format multiplies the number by 100 and displays the result with a percent symbol (%) to its right, with two digits to the right of the decimal point.
Scientific Scientific format uses standard scientific notation (exponential format), providing two significant digits.
Yes/No If number is 0 this format displays No, otherwise it displays Yes.
True/False If number is 0 this format displays False, otherwise it displays True.
On/Off If number is 0 this format displays Off, otherwise it displays On.

 

 

 

Example: Using Predefined Named Numeric formats.

 

Sub NamedNumericFormats()
'Using Predefined Named Numeric formats.


Dim str As Variant


'returns "5678.9523"

str = Format(5678.9523, "General Number")

MsgBox str


'returns "$5,678.95"

str = Format(5678.9523, "Currency")

MsgBox str


'returns "5678.90"

str = Format(5678.9, "Fixed")

MsgBox str


'returns "5,678.95"

str = Format(5678.9523, "Standard")

MsgBox str


'returns "595.23%"

str = Format(5.9523, "Percent")

MsgBox str


'returns "5.68E+03"

str = Format(5678.9523, "Scientific")

MsgBox str


'returns "Yes"

str = Format(-5.95, "Yes/No")

MsgBox str


'returns "True"

str = Format(5.95, "True/False")

MsgBox str


'returns "Off"

str = Format(0, "On/Off")

MsgBox str


End Sub

 

 

 

Characters used to create User-Defined Number Formats with the VBA Format Function

 

    Syntax for VBA Format Function: Format(expression,format)
Character Description Format  Argument Expression Argument Formatted Display
0 (zero) Digit placeholder. If the number has lesser number of digits than zeros in the format code, the insignificant zeros are displayed. This means that the minimum number of digits are determined by the position of zero at the extreme left before decimal and position of zero at extreme right after decimal, in the format code. 0.00 5.6 5.60
  If the number has more digits than zeros to the left of the decimal point in the format code, the extra digits are displayed. 00.00 5.6 05.60
  The number of zeros to the right of the decimal point in the format code, determine the round off digits. The "00" format code rounds off to the nearest digit preceding the decimal point. 0.0 5.6 5.6
    0 0.6 1
    00.00 456.789 456.79
    00 45.445 45
         
# (number character) Digit placeholder. This follows the same rules as 0 (zero), except that, if the number has lesser number of digits than "#" characters in the format code, the insignificant zeros are NOT displayed, even though it may be the only digit. ###.## 456.6 456.6
  If the number has more digits than # characters to the left of the decimal point in the format code, the extra digits are displayed. # 456.68 457
  The number of # to the right of the decimal point in the format code, determine the round off digits. The "##" format code rounds off to the nearest digit preceding the decimal point. (###) ### - #### 4567891234 (456) 789 - 1234
    ##.# 456.689 456.7
    ## 45.678 46
         
. (period) Decimal placeholder. The decimal point (ie. the "." character) in the format code determines the decimal place. Some locales use comma as the decimal separator instead of period. 00.000 456.123456 456.123
  The number of Digit Placeholders to the right of the decimal point in the format code, determine the round off digits. For the first digit placeholder to the left of the decimal separator use 0 to display a leading zero with fractional numbers. 00.00 456.789567 456.79
  The "00" or "##" format codes round off to the nearest digit preceding the decimal point. ##.# 456.789567 456.8
    ##.# 0.65 7
         
% (percent sign) Percentage indicator. Numbers are displayed as a percentage of 100 with this. The percent sign in the format code multiplies the number by 100, before it is formatted. The symbol "%" is displayed at the same position at which it is inserted in the format code. #.0% 0.00625 .6%
    0.000% 0.00625 0.625%
    #.##% 0.00625 .63%
    %# 0.5625 %1
    #% 0.5625 56%
         
, (comma) Thousand separator and Number scaling. Some locales use period (.) as a thousand separator. # 123456 123456
  Thousand separator: In the format code, placing comma between two digit placeholders and to the left of decimal, will act as a thousand separator. #,### 123456 123,456
  Number Scaling: If comma is placed to the immediate left of the decimal point (in the format code), the number is divided by 1,000, n number of times wherein n is the number of characters ",". The format string "0,," will scale down the number 100 million to 100 (divides 100 million by 1,000 * 1,000); and the format code "0,,," will divide the number by 1,000 * 1,000 * 1,000. Note that this number scaling will not apply the thousand separator, which will have to be done separately after the number scaling. A comma in any position other than to the immediate left of the decimal point will only act as a thousand separator. #,#00 123456 123,456
    #,###.## 4567.234 4,567.23
    0, 10000 10
    #,##0,, 1000000 1
    #,###.#, 12345.678 12,345.7
    #,###.# 12345.678 12,345.7
         
: Time separator. This separates hours, minutes & seconds while formatting time values. hh:mm:ss AMPM 0.251 06:01:26 AM
         
/ (forward slash) Date separator. This separates the day, month & year while formatting date values. dd/mm/yyyy 7/24/2014 24/07/2014
    mm/dd/yyyy 41476 07/21/2013
         
E+   E-   e+   e- Scientific notation (exponential format). "E+" and "E-" followed by atleast one digit placeholder (0 or #), displays the number in scientific notation, with the character "E"  mentioned between the number and the exponent. The number of "0" characters determine the minimum number of exponent digits. "E+" indicates that the sign character (plus or minus) will always precede the exponent, whereas "E-" indicates that the sign character (minus) precedes only negative exponents. 0.00E+0 4560000 4.56E+6
  The E stands for exponent. To avoid writing extremely long numbers, use scientific notation (SN), ie. a numeric value containing the letter E followed by a number. To convert a SN number say 5.0E+3 to the actual number, move the decimal position 3 positions to the right OR multiply the number to the left of E by 10 raised to the powerof 3 viz. the actual number is 5000. If the exponent is negative, like in 5.25E-3, move the decimal position 3 positions to the left OR multiply the number to the left of E by 10 raised to the power of -3 viz. the actual number is 0.00525. #0.0E+00 4560000 45.6E+05
    0.###E+0 123.456 1.235E+2
    ##E+# 0.0001234 12E-5
    ##E-0 123456 12E4
    ##E+0 123456 12E+4
    ##E-0 0.0001234 12E-5
    0.##E+0 0.00525 5.25E-3
         
$  +  -  (  )  space Literal characters. These  are displayed as literals (exactly as typed) as per their position in the format code. Use these to display currency, to differentiate positive and negative numbers and for a more user-friendly display. $ +#,###.00 1456.7 $ +1,456.70
         
\ (backslash) Backslash. Any character appearing after backslash (\) will display as a literal, even though it may be reserved as an operator (say, %). Backlash itself will not be displayed. The number 0.75 with the format code #.00% will format to 75.00%, but with the format code #.00\% it will format to .75%, ie. format code will not use % as operator but as a literal. To display several characters as literals enclose these in double quotation marks (" ") or in case of a single character, precede it with a backslash (\). #.00\% 0.75 .75%
  Many Characters do not display as literal, except when preceded with a backlash - some examples are: date/ time-formatting characters (c, d, h, m, n, q, s, w, y, / and :), the numeric-formatting characters (#, 0, and period), and string-formatting characters (@, &, <, >, and !). #.00% 0.75 75.00%
  Precede String with "Hello " \H\e\l\l\o @ Tracy Hello Tracy
  character c does not display as literal, unless preceded with a backlash c @ Tracy Tracy
  character c does not display as literal, unless preceded with a backlash \c @ Tracy c Tracy
  character b displays as literal, without being preceded with a backlash b @ Tracy b Tracy
  " kg” will be added to the end of the number 0 kg 75 75 kg
         
(" ") double quotation marks The string between the double quotation marks ("") is displayed.      
  The vba Chr function returns a character (string data type) identified to the specified character code - use Chr(34) in your code for a quotation mark (") ex. MsgBox Chr(34) & ActiveCell.Value & Chr(34) returns the ActiveCell value within double quotation marks.      

 

 

Example: Using User-defined Number formats with the VBA Format Function.

 

Sub UserDefinedNumberFormats()
'Using User-defined Number formats with the VBA Format Function.


Dim str As Variant


'returns "5678.95"

str = Format(5678.9523, "0.00")

MsgBox str


'returns "05.90"

str = Format(5.9, "00.00")

MsgBox str


'returns "5.9"

str = Format(5.9, "##.##")

MsgBox str


'returns "5.95"

str = Format(5.9523, "##.00")

MsgBox str


'returns "5679"

str = Format(5678.9523, "#")

MsgBox str


'returns "$5672.5"

str = Format(5672.4523, "##.#")

MsgBox str


'returns "5,678.95"

str = Format(5678.9523, "#,###.##")

MsgBox str


'returns "(456) 789 - 1234"

str = Format(4567891234#, "(###) ### - ####")

MsgBox str


'returns ".63%"

str = Format(0.00625, "#.##%")

MsgBox str


'returns "%1"

str = Format(0.625, "%#")

MsgBox str


'returns "4.56E+6"

str = Format(4560000, "0.00E+0")

MsgBox str


'returns "45.6E+05"

str = Format(4560000, "#0.0E+00")

MsgBox str


'returns "12E4"

str = Format(123456, "##E-0")

MsgBox str


'returns "12E+4"

str = Format(123456, "##E+0")

MsgBox str


'returns "$ +1,456.70"

str = Format(1456.7, "$ +#,###.00")

MsgBox str


'returns "Hello Tracy"

str = Format("Tracy", "\H\e\l\l\o @")

MsgBox str


'returns "75 kg"

str = Format("75", "0 kg")

MsgBox str


End Sub

 

 

 

VBA Format Function can have upto Four Sections for User-defined Formats, for different Formats for different Numeric Values

 

While creating User-Defined Number Formats with the VBA Format Function, you can have upto 4 sections, each section being separated by semicolons(;), wherein you can create different formats for different Numeric values. Creating multiple sections is not possible wherein the format argument contains any Predefined Named Numeric format.

 

There can be upto four sections of format argument, wherein each section is separated by a semicolon. These sections determine the display of positive values, negative values, zeros and Null values, in that order. If only one section is specified, it applies to all values; if two sections are specified, the first applies to positive and zero values and the second section applies to negative values. When you use 3 sections for format argument, the first section applies to positive values, the second section applies to negative values, and the third section applies to zeros.

 

 

Example: Using multiple sections for user-defined Number formats with the VBA Format Function.

 

Sub MultipleSectionsUserDefinedNumberFormats()
'Using multiple sections for user-defined Number formats with the VBA Format Function.

 

Dim str As Variant

 

'returns "5,678.952"

str = Format(5678.9523, "#,###.000;($ #,##0);0.00;Null")

MsgBox str


'returns "($ 5,679)"

str = Format(-5678.9523, "#,###.000;($ #,##0);0.00;Null")

MsgBox str


'returns "0.00"

str = Format(0, "#,###.000;($ #,##0);0.00;Null")

MsgBox str


End Sub

 

 

 

Missing a Section:

 

You can also skip a section and specify format argument for the following or preceding section, but then you must enter the ending semicolon for the skipped section. The skipped section is printed using the format of the positive value, and in the absence of a format for a positive value, skipping a section will result in a blank display for that section. See below example.

 

 

Example: Missing sections for user-defined Number formats with the VBA Format Function.

 

Sub MissingSectionsUserDefinedNumberFormats()
'missing sections for user-defined Number formats with the VBA Format Function.


Dim str As Variant


'returns "" ie. blank (positive expression, but no format argument for positive value)
str = Format(5678.9523, ";($ #,##0);Zero;")
MsgBox str

'returns "-5,678.952" (for negative expression, using the format of the positive value when no format argument for negative value)
str = Format(-5678.9523, "#,###.000;;Zero")
MsgBox str

'returns "" ie. blank (negative expression, no format argument for positive or negative values)
str = Format(-5678.9523, ";;")
MsgBox str

'returns "($ 5,679)" (for negative expression, using format argument for negative values)
str = Format(-5678.9523, ";($ #,##0);")
MsgBox str

'returns "zero" (for zero expression, using format argument for zero values)
str = Format(0, ";;\z\e\r\o")
MsgBox str

'returns ".000" (for zero expression, using the format of the positive value)

str = Format(0, "#,###.000;;")

MsgBox str


End Sub

 

 

 

Characters used to create User-Defined Date & Time Formats with the VBA Format Function

 

Character Description Format Argument Expression Argument Formatted Display
/ (forward slash) Date separator. Separates the day, month & year while formatting date values. mm/dd/yyyy 41463 07/08/2013
c Date is displayed as ddddd and time is displayed as ttttt, in that order. Only date is displayed if date serial number does not have a fractional part and only time information is displayed if no integer portion. c 41463.251 7/8/2013 6:01:26 AM
    c 0.251 6:01:26 AM
    c 41463 7/8/2013
d Day is displayed as a number, as one digit or as two digit, without a leading zero. (1-31) mm/d/yyyy 41463 07/8/2013
dd Day is displayed as a number, as two digit, with a leading zero where applicable. (01-31) mm/dd/yyyy 41463 07/08/2013
ddd Day is abbreviated to three letters, viz. Sunday is displayed as Sun. (Sun-Sat) ddd, mmm d, yyyy 41463 Mon, Jul 8, 2013
dddd Day is displayed in its full format, viz. Sunday is displayed as Sunday. (Sunday-Saturday) dddd, mmm d, yyyy 41463 Monday, Jul 8, 2013
ddddd Display a date serial number as a complete date (including day, month, and year) formatted according to the short date setting recognized by your system. The default short date format is m/d/yy. ddddd 41463 7/8/2013 (Short Date Format in the system showing the display is: dddd, m/d/yyyy)
dddddd Display a date serial number as a complete date (including day, month, and year) formatted according to the long date setting recognized by your system. The default long date format is mmmm dd, yyyy. dddddd 41463 Monday, July 8, 2013  (Long Date Format in the system showing the display is: dddd, MMMM d, yyyy)
aaaa Displays the full, localized name of the day in its full format (same as dddd, except that its localized version).       
w Day of the week is displayed as a number (1-7 for Sunday-Saturday).  w, mmm d, yyyy  41463 2, Jul 8, 2013 
ww  Week of the year is displayed as a number. (1 to 54) ww #7/8/2013# 28
m Month is displayed as a number, as one digit or as two digit, without a leading zero - (1-12).  To use m as minute(s), it should appear immediately after the h or hh code, such as "h:m".  m/d/yyyy 41463 7/8/2013 
mm Month is displayed as a number, as two digit, with a leading zero where applicable - (01-12). To use mm as minute(s), it should appear immediately after the h or hh code, such as "h:mm".  mm/d/yyyy  41463 07/8/2013 
mmm Month name is abbreviated to three letters, viz. January is displayed as Jan. (Jan-Dec)  mmm d, yyyy  41463 Jul 8, 2013 
mmmm Month is displayed in its full name, viz. January is displayed as January. (January-December)  mmmm d, yyyy  41463 July 8, 2013 
oooo Displays the full localized name of the month (same as mmmm, except that its localized version).      
q Quarter of the year is displayed as a number. (1 to 4)  q #7/8/2013#  3
y Day of the year is displayed as a number. (1 to 366)  y #7/8/2013#  189
yy Year is displayed as a number in two digits, viz. last 2 digits of the year are displayed. (00-99)  m/d/yy  41463 7/8/13 
yyyy Year is displayed as a number in four digits, viz. all digits of the year are displayed. (1900-9999)  m/d/yyyy  41463 7/8/2013 
         
Time separator. This separates hours, minutes & seconds while formatting time values.  h:n:ss AMPM  0.251 6:1:26 AM 
h Hour is displayed as a number, as one digit or as two digit, without leading zeros. (0-23)  h:nn:ss AMPM  0.251 6:01:26 AM 
Hh Hour is displayed as a number, as two digit, with a leading zero where applicable. (00-23)  Hh:n:ss AMPM  0.251 06:1:26 AM 
N Minute is displayed as a number, as one digit or as two digit, without leading zeros -  (0 to 59). You can also use m code as minute (m is used for displaying month), for which it should appear immediately after the h or hh code, such as "h:m".  n:ss  0.251 1:26
Nn Minute is displayed as a number, as two digit, with a leading zero where applicable -  (00 to 59). You can also use m code as minute (m is used for displaying month), for which it should appear immediately after the h or hh code, such as "h:m".  Nn:s  0.251 01:26 
S Second is displayed as a number, as one digit or as two digit, without leading zeros. (0 - 59)  h:n:S 0.2591 6:13:6 
Ss Second is displayed as a number, as two digit, with a leading zero where applicable.  (00 - 59)  h:n:Ss 0.2591 6:13:06 
t t t t t   Complete time is displayed (including hour, minute, and second) wherein the time separator, as defined by the time format recognized by your system, is used. If the leading zero option is selected and the time is before 10:00 AM / PM, a leading zero will be displayed. h:mm:ss is the default format.  ttttt  0.25631  6:09:05 AM 
AM/PM, am/pm, A/P, a/p or AMPM If these codes are included in the format, the hour is displayed using a 12-hour clock, else the hour is based on the 24-hour format. Display will include AM, am, A or a for a time before noon, and PM, pm, P or p for a time 'from' and 'after' noon till 11:59 PM. While using AMPM, the case can be UPPER or lower, matching the string as defined by your system settings. AM/PM is the Default format. Hh:n:ss A/P 0.251 06:1:26 A

 

 

 

Example: Using User-defined Date & Time formats with the VBA Format Function.

 

Sub UserDefinedDateTimeFormats()
'returns the Date and Time per user defined format


Dim MyDate As Variant, MyTime As Variant, str As Variant

 

MyDate = #7/1/2014#
MyTime = #7:09:32 PM#


'returns "07/01/2014"

str = Format(MyDate, "mm/dd/yyyy")

MsgBox str


'returns "07/08/2013"

str = Format(41463, "mm/dd/yyyy")

MsgBox str


'returns "7/8/13"

str = Format(41463, "m/d/yy")

MsgBox str


'returns "7/8/2013 6:01:26 AM" - Date is displayed as ddddd and time is displayed as ttttt, in that order.

str = Format(41463.251, "c")

MsgBox str


'returns "6:01:26 AM" - only time information is displayed if no integer portion.

str = Format(0.251, "c")

MsgBox str


'returns "2" - Day of the week is displayed as a number (1-7 for Sunday-Saturday).

str = Format(41463, "w")

MsgBox str


'returns "28" - Week of the year is displayed as a number (1 to 54).

str = Format(#7/8/2013#, "ww")

MsgBox str


'returns "3" - Quarter of the year is displayed as a number (1 to 4)

str = Format(#7/8/2013#, "q")

MsgBox str


'returns "189" - Day of the year is displayed as a number (1 to 366)

str = Format(#7/8/2013#, "y")

MsgBox str


'returns "7/1/14"

str = Format(MyDate, "m/d/yy")

MsgBox str


'returns "Tue, Jul 1, 2014"

str = Format(MyDate, "ddd, mmm d, yyyy")

MsgBox str


'returns "19:9:32"

str = Format(MyTime, "h:n:s")

MsgBox str


'returns "07:09:32 pm"

str = Format(MyTime, "hh:mm:ss am/pm")

MsgBox str

 

'returns "07:09:32 PM"

str = Format(MyTime, "hh:mm:ss AMPM")

MsgBox str


'returns "06:1:26 A"

str = Format(0.251, "Hh:n:ss A/P")

MsgBox str


'returns "6:09:05 AM" - Complete time is displayed (including hour, minute, and second)

str = Format(0.25631, "ttttt")

MsgBox str


'omitting the format argument will return a String representation of the number - "245"

str = Format(245)

MsgBox str


End Sub

 

 

 

Characters used to create User-Defined String Formats with the VBA Format Function

 

Character Description Format Argument Expression Argument Formatted Display
@ (at character) Character placeholder. Display actual character or space. If character appears in the position where @ apepars in the format string, the character is displayed, else a space is displayed at that position. Placeholders will be filled from right to left, unless exclamation (!) character is used in the format string as explained below. @@@@@@@ Excel   Excel
(2 leading spaces appear on the left of "Excel")
  Precede String with "Mr " "Mr "@ James Mr James
  Precede String with "Hello " \H\e\l\l\o @ Tracy Hello Tracy
& Character placeholder. Display actual character or nothing. If character appears in the position where & (ampersand) appears in the format string, the character is displayed, else a nothing is displayed at that position. Placeholders will be filled from right to left, unless exclamation (!) character is used in the format string as explained below. &&&&&&&&& Excel VBA Excel VBA
(Displays "Excel VBA" as in the String)
> Displays all characters as uppercase. > Excel EXCEL
< Displays all characters as lowercase. < Excel excel
! Placeholders will be filled from left to right - Default is right to left. !@@@@@@@ Excel Excel  
(2 spaces appear on the right of "Excel")

 

 

 

Example: Using User-defined String formats with the VBA Format Function.

 

Sub UserDefinedStringFormats()
'Using User-defined String formats with the VBA Format Function.


Dim str As Variant


'returns "  Excel" & 7 - (2 leading spaces appear on the left of "Excel")

str = Format("Excel", "@@@@@@@")

MsgBox str

MsgBox Len(str)

'returns "Excel  " & 7 - (2 leading spaces appear on the right of "Excel")

str = Format("Excel", "!@@@@@@@")

MsgBox str

MsgBox Len(str)


'returns "Mr James" - Precede String with "Mr "

str = Format("James", """Mr ""@")

MsgBox str


'returns "Hello Tracy" - Precede String with "Hello "

str = Format("Tracy", "\H\e\l\l\o @")

MsgBox str


'returns "EXCEL" - Displays all characters as uppercase.

str = Format("Excel", ">")

MsgBox str


'returns "excel" - Displays all characters as lowercase.

str = Format("Excel", "<")

MsgBox str


End Sub

 

 

 

 

VBA Format Function can have One or Two Sections for User-defined Formats, for different Formats for different String Values

 

While creating User-Defined String Formats with the VBA Format Function, you can have One or Two sections, each section being separated by semicolons(;), wherein you can create different formats for different String values. If only one section is specified, it applies to all string data; if two sections are specified, the first applies applies to string data, and the second section applies to Null values and zero-length strings ("").